feat(host): vendor PyroWave + minimal Granite subset as crates/pyrowave-sys

Phase 0 of design/pyrowave-codec-plan.md — the opt-in wired-LAN ultra-low- latency codec. Vendored at upstream 509e4f88 (API 0.4.0, Granite 44362775, volk + vulkan-headers pins in PUNKTFUNK-VENDOR.txt), pruned to the 6.6 MB the standalone no-renderer build needs; scripts/vendor-pyrowave.sh reproduces the tree (a pin bump is protocol-affecting, plan §4.2). build.rs drives the wrapper CMakeLists (static archives incl. a static C-API lib upstream only ships shared) + bindgen over pyrowave.h; Linux and Windows only, empty stub elsewhere (Apple gets a native Metal port, §4.7). Offline-safe by construction: no network, no system lib, vendored Vulkan headers — same model as the opus dep (flatpak builder has no network). Phase-0 validation on .21 (RTX 5070 Ti, driver 610.43.03): - upstream pyrowave-c-test + interop test (incl. dmabuf/DRM-modifier Vulkan<->Vulkan) pass, from the pristine AND the pruned tree - GPU kernel times at ~1.6 bpp noise: encode/decode 0.090/0.042 ms @800p, 0.146/0.067 @1080p, 0.226/0.103 @1440p, 0.477/0.201 @4K — order of magnitude under NVENC's 1-2 ms retrieve, CBR lands within ~100 B of target - cargo test -p pyrowave-sys green (static link + API-version pin check) Co-Authored-By: Claude Fable 5 <noreply@anthropic.com>
2026-07-15 00:35:10 +02:00
parent 1b73361372
commit 4c3b11445c
396 changed files with 140058 additions and 0 deletions
@@ -0,0 +1,81 @@
+#version 450
+// Copyright (c) 2025 Hans-Kristian Arntzen
+// SPDX-License-Identifier: MIT
+#extension GL_KHR_shader_subgroup_basic : require
+#extension GL_KHR_shader_subgroup_ballot : require
+#extension GL_KHR_shader_subgroup_arithmetic : require
+#extension GL_KHR_shader_subgroup_shuffle_relative : require
+#extension GL_KHR_shader_subgroup_shuffle : require
+
+layout(local_size_x_id = 0) in;
+
+struct RDOperation
+{
+    int quant;
+    uint block_offset_saving;
+};
+
+const int BLOCK_SPACE_SUBDIVISION = 16;
+
+layout(set = 0, binding = 0) readonly buffer Buckets
+{
+    layout(offset = 4) int consumed_payload;
+    layout(offset = 64) int total_savings_per_bucket[128 * BLOCK_SPACE_SUBDIVISION];
+    RDOperation rdo_operations[];
+} buckets;
+
+layout(set = 0, binding = 1) buffer QuantList
+{
+    int data[];
+} quant_data;
+
+layout(push_constant) uniform Registers
+{
+    uint target_payload_size;
+    uint num_blocks_per_subdivision;
+} registers;
+
+void main()
+{
+    int required_savings_per_bucket = int(buckets.consumed_payload) - int(registers.target_payload_size);
+    if (gl_WorkGroupID.x != 0)
+    {
+        int prev_bucket_total = buckets.total_savings_per_bucket[gl_WorkGroupID.x - 1];
+        // This bucket is empty.
+        if (buckets.total_savings_per_bucket[gl_WorkGroupID.x] == prev_bucket_total)
+            return;
+
+        required_savings_per_bucket -= prev_bucket_total;
+    }
+    else
+    {
+        // This bucket is empty.
+        if (buckets.total_savings_per_bucket[gl_WorkGroupID.x] == 0)
+            return;
+    }
+
+    // If all previous buckets can complete the job, skip.
+    if (required_savings_per_bucket <= 0)
+        return;
+
+    uint total_saved = 0;
+
+    for (uint i = 0; i < registers.num_blocks_per_subdivision && total_saved < required_savings_per_bucket; i += gl_SubgroupSize)
+    {
+        RDOperation op = RDOperation(0, 0);
+        if (i + gl_SubgroupInvocationID < registers.num_blocks_per_subdivision)
+            op = buckets.rdo_operations[gl_WorkGroupID.x * registers.num_blocks_per_subdivision + i + gl_SubgroupInvocationID];
+
+        uint saving = bitfieldExtract(op.block_offset_saving, 16, 16);
+        uint block_offset = bitfieldExtract(op.block_offset_saving, 0, 16);
+
+        uint scan_saving = subgroupInclusiveAdd(saving);
+
+        bool should_apply_quant = total_saved + scan_saving - saving < required_savings_per_bucket;
+        if (should_apply_quant && saving != 0)
+            atomicMax(quant_data.data[block_offset], op.quant);
+
+        total_saved += subgroupShuffle(scan_saving, gl_SubgroupSize - 1);
+    }
+}
+